Инициализировать загрузку частями

Инициализирует загрузку объекта по частям

Функция ИнициализироватьЗагрузкуЧастями(Знач Наименование, Знач Бакет, Знач ОсновныеДанные, Знач Заголовки = Неопределено, Знач Каталог = Ложь) Экспорт

Параметр	CLI опция	Тип	Обяз.	Назначение
Наименование	--name	Строка	✔	Наименование объекта в бакете
Бакет	--bucket	Строка	✔	Имя бакета для загрузки объекта
ОсновныеДанные	--basic	Структура Из КлючИЗначение	✔	Основные данные запроса. См. ПолучитьСтруктуруДанных
Заголовки	--headers	Соответствие Из КлючИЗначение	✖	Дополнительные заголовки запроса, если необходимо
Каталог	--dir	Булево	✖	Истина > Path style URL, Ложь > Virtual hosted style URL

Возвращаемое значение: Структура Из КлючИЗначение - сериализованный JSON ответа от хранилища

подсказка

Метод в документации AWS: CreateMultipartUpload

Это служебный метод. Для простого сценария загрузки файлов предназначен единый метод ЗагрузитьОбъект
Использование загрузки частями для файлов < 5 МБ или при размере одной части < 5 МБ приведет к ошибке

Пример использования для 1С:Предприятие/OneScript

    URL       = "storage-155.s3hoster.by";
    AccessKey = "BRN5RKJE67...";
    SecretKey = "NNhv+i9PrytpT8Tu0C1N...";
    Region    = "BTC";

    ОсновныеДанные = OPI_S3.ПолучитьСтруктуруДанных(URL, AccessKey, SecretKey, Region);

    Наименование = "fileChunked.mp3";

    Каталог = Истина; // Формирование URL в path-style
    Бакет = "opi-dirbucket3";
    Содержимое = "https://hut.openintegrations.dev/test_data/song.mp3"; // URL, Путь или Двоичные данные
    Содержимое = OPI_ЗапросыHTTP.Get(Содержимое);

    Результат = OPI_S3.ИнициализироватьЗагрузкуЧастями(Наименование, Бакет, ОсновныеДанные, , Каталог);
    // ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^

    IDЗагрузки    = Результат["response"]["InitiateMultipartUploadResult"]["UploadId"];
    ОбщийРазмер   = Содержимое.Размер();
    РазмерУчастка = 5242880;
    ПрочитаноБайт = 0;
    НомерЧасти    = 1;

    ЧтениеДанных  = Новый ЧтениеДанных(Содержимое);
    ИсходныйПоток = ЧтениеДанных.ИсходныйПоток();
    МассивТегов   = Новый Массив;

    Пока ПрочитаноБайт < ОбщийРазмер Цикл

        ТекущееЧтение = ЧтениеДанных.Прочитать(РазмерУчастка);
        ТекущиеДанные = ТекущееЧтение.ПолучитьДвоичныеДанные();

        Если ТекущиеДанные.Размер() = 0 Тогда
            Прервать;
        КонецЕсли;

        Результат = OPI_S3.ЗагрузитьЧастьОбъекта(Наименование
            , Бакет
            , ОсновныеДанные
            , IDЗагрузки
            , НомерЧасти
            , ТекущиеДанные
            , Каталог);

        ПрочитаноБайт = ИсходныйПоток.ТекущаяПозиция();

        ETag = Результат["headers"]["Etag"];
        ETag = ?(ETag = Неопределено, Результат["headers"]["ETag"], ETag);

        МассивТегов.Добавить(ETag);

        НомерЧасти = НомерЧасти + 1;

    КонецЦикла;

    Результат = OPI_S3.ЗавершитьЗагрузкуЧастями(Наименование, Бакет, ОсновныеДанные, IDЗагрузки, МассивТегов, , Каталог);

Bash

    oint s3 ИнициализироватьЗагрузкуЧастями \
      --name "fileChunked.mp3" \
      --bucket "opi-dirbucket3" \
      --basic "{'URL':'storage-155.s3hoster.by','AccessKey':'***','SecretKey':'***','Region':'BTC','Service':'s3'}" \
      --dir true

CMD/Bat

    oint s3 ИнициализироватьЗагрузкуЧастями ^
      --name "fileChunked.mp3" ^
      --bucket "opi-dirbucket3" ^
      --basic "{'URL':'storage-155.s3hoster.by','AccessKey':'***','SecretKey':'***','Region':'BTC','Service':'s3'}" ^
      --dir true

Результат

{
 "status": 200,
 "response": {
  "InitiateMultipartUploadResult": {
   "Bucket": "opi-dirbucket3",
   "Key": "fileChunked.mp3",
   "UploadId": "MDk2NGE5MDUtNDcxZS00ZDljLTkzYjMtODM5ZDM4NGMyMWVhLmNmYjQ2MGUwLTM4ZTItNDIyMi1iOWI5LTIxZTM0ZDRmYWRjYg"
  }
 },
 "headers": {
  "Accept-Ranges": "bytes",
  "Date": "Tue, 09 Sep 2025 19:14:36 GMT",
  "Server": "MinIO",
  "Strict-Transport-Security": "max-age=31536000; includeSubDomains",
  "Vary": "Origin, Accept-Encoding",
  "X-Amz-Id-2": "93c576aa54c960b355da9e2934476635fe3243f5df9dbb4db8b7c0d94bec7cd1",
  "X-Amz-Request-Id": "1863B32B00A56B92",
  "X-Content-Type-Options": "nosniff",
  "X-XSS-Protection": "1; mode=block",
  "Content-Length": "326",
  "Content-Type": "application/xml"
 }
}