Получить записи

Получает записи из выбранной таблицы

Функция ПолучитьЗаписи(Знач Таблица, Знач Поля = "*", Знач Фильтры = "", Знач Сортировка = "", Знач Количество = "", Знач Соединение = "", Знач Tls = "") Экспорт

Параметр	CLI опция	Тип	Обяз.	Назначение
Таблица	--table	Строка	✔	Имя таблицы
Поля	--fields	Массив Из Строка	✖	Поля для выборки
Фильтры	--filter	Массив Из Структура	✖	Массив фильтров. См. ПолучитьСтруктуруФильтраЗаписей
Сортировка	--order	Структура Из КлючИЗначение	✖	Сортировка: Ключ > поле, Значение > направление (ASC, DESC)
Количество	--limit	Число	✖	Ограничение количества получаемых строк
Соединение	--dbc	Строка, Произвольный	✖	Соединение или строка подключения
Tls	--tls	Структура Из КлючИЗначение	✖	Настройки TLS, если необходимо. См. ПолучитьНастройкиTls

Возвращаемое значение: Соответствие Из КлючИЗначение - Результат выполнения запроса

Пример использования для 1С:Предприятие/OneScript

    Адрес  = "127.0.0.1";
    Логин  = "bayselonarrend";
    Пароль = "12we...";
    База   = "testbase1";

    СтрокаПодключения = OPI_MySQL.СформироватьСтрокуПодключения(Адрес, База, Логин, Пароль);

    // Все записи без отборов

    Таблица = "testtable";

    // При использовании строки подключения инициализируется новое соединение,
    // которое будет закрыто после выполнения функции.
    // В случае выполнения нескольких операций желательно использовать одно соединение,
    // заранее созданное функцией ОткрытьСоединение()
    Результат = OPI_MySQL.ПолучитьЗаписи(Таблица, , , , , СтрокаПодключения);

    // Отборы, выбранные поля, количество и сортировка

    СтрокаПодключения = OPI_MySQL.СформироватьСтрокуПодключения(Адрес, "test_data", Логин, Пароль);

    Таблица = "test_data";

    Поля = Новый Массив;
    Поля.Добавить("first_name");
    Поля.Добавить("last_name");
    Поля.Добавить("email");

    Фильтры = Новый Массив;

    СтруктураФильтра1 = Новый Структура;

    СтруктураФильтра1.Вставить("field", "gender");
    СтруктураФильтра1.Вставить("type" , "=");
    СтруктураФильтра1.Вставить("value", "Male");
    СтруктураФильтра1.Вставить("union", "AND");
    СтруктураФильтра1.Вставить("raw"  , Ложь);

    СтруктураФильтра2 = Новый Структура;

    СтруктураФильтра2.Вставить("field", "id");
    СтруктураФильтра2.Вставить("type" , "BETWEEN");
    СтруктураФильтра2.Вставить("value", "20 AND 50");
    СтруктураФильтра2.Вставить("raw"  , Истина);

    Фильтры.Добавить(СтруктураФильтра1);
    Фильтры.Добавить(СтруктураФильтра2);

    Сортировка = Новый Структура("ip_address", "DESC");
    Количество = 5;

    Результат = OPI_MySQL.ПолучитьЗаписи(Таблица, Поля, Фильтры, Сортировка, Количество, СтрокаПодключения);

Bash

    oint mysql ПолучитьЗаписи \
      --table "testtable" \
      --dbc "mysql://bayselonarrend:***@127.0.0.1:3306/"

CMD/Bat

    oint mysql ПолучитьЗаписи ^
      --table "testtable" ^
      --dbc "mysql://bayselonarrend:***@127.0.0.1:3306/"

Результат

{
 "data": [
  {
   "bigint_field": 9223372036854775807,
   "char_field": "AAAAA",
   "date_field": "2025-04-06T03:00:00+03:00",
   "datetime_field": "2025-04-06T03:23:50+03:00",
   "double_field": 100.51212310791,
   "float_field": 100.5,
   "int_field": -2147483647,
   "longtext_field": "Some looooooong text",
   "mediumblob_field": {
    "BYTES": "/9j/4VTBRX..."
   },
   "mediumint_field": 8388607,
   "mediumtext_field": "Some medium text",
   "set_field": "one",
   "smallint_field": -32767,
   "text_field": "Some text",
   "time_field": "1970-01-01T03:23:50+03:00",
   "timestamp_field": "2025-04-06T03:23:50+03:00",
   "tinyint_field": 127,
   "tinytext_field": "Some tiny text",
   "uint_field": 4294967295,
   "varchar_field": "Some varchar"
  }
 ],
 "result": true
}